dbDemo

Option Explicit

Private Const CONNECTIONSTRING        = "FILEDSN=C:\dsn\Intranet.dsn;DATABASE=Intranet"
Private Const CONNECTIONSTRINGSHAPE = "Provider=MSDataShape;FILEDSN=C:\dsn\Intranet.dsn;DATABASE=Intranet"

Dim utdb
Set utdb = CreateObject("utilDatabase.WSC")

Public Function GetDemo(idDemo)
    Dim cn,sSQL
    sSQL = "SELECT * FROM Demo WHERE ID = " & utdb.EncodeN(idDemo)
    Set cn = CreateObject("ADODB.Connection")
    cn.Open CONNECTIONSTRING
    Set GetDemo = cn.Execute(sSQL)
End Function

Public Function Search(sName,iAge,dtFrom,dtTo)
    Dim    cn
    Dim sSQL,sWhere
    
    sSQL = "SELECT * FROM Demo"
    If sName & "" <> "" Then
        sWhere = sWhere & " AND Name = " & utdb.EncodeS(sName)
    End If
    If IsNumeric(iAge) Then
        sWhere = sWhere & " AND Age = " & utdb.EncodeN(iAge)
    End If
    If IsDate(dtFrom) Then
        sWhere = sWhere & " AND Date >= " & utdb.EncodeT(dtFrom)
    End If
    If IsDate(dtTo) Then
        sWhere = sWhere & " AND Date < " & utdb.EncodeT(CDate(dtTo) + 1)
    End If
    If sWhere & "" <> "" Then
        sSQL = sSQL & " WHERE " & Mid(sWhere,5)
    End If

    Set cn = CreateObject("ADODB.Connection")
    cn.Open CONNECTIONSTRING
    Set Search = cn.Execute(sSQL)
End Function

Public Function AddDemo(sName,iAge)
    Dim cn,cmd,rs
    Dim sSQL,i
    
    sSQL = "INSERT INTO Demo(Name,Age) VALUES(?,?)"

    Set cn = CreateObject("ADODB.Connection")
    cn.Open CONNECTIONSTRING
    Set cmd = CreateObject("ADODB.Command")
    cmd.ActiveConnection = cn
    cmd.CommandText = sSQL
    i = -1
    i = i + 1    :    cmd.Parameters(i) = sName
    i = i + 1    :    cmd.Parameters(i) = iAge
    Call cmd.Execute()

    Set rs = CreateObject("ADODB.Recordset")
    rs.Open "SELECT @@IDENTITY AS ‘Identity‘",cn
    AddDemo = CLng(rs("Identity"))
    rs.Close
    cn.Close
End Function