bat文件自动创建cocos2dx 工程

时间：2014-05-27 03:05:02 阅读：697 评论：0 收藏：0 [点我收藏+]

1. 写在开头

本人写了一个自动创建cocos2dx工程的脚本。.bat文件，会修正Application.mk 文件，并且在桌面创建打开项目目录的快捷方式。

使用条件：1. 在本地计算机中已安装python 2.7.6 版本，并将python安装目录加入到 PATH环境变量中。

　　　　　2. 根据自己的cocos2dx与ndk安装目录，更改脚本最初COCOS2DX_DIR、NDK_DIR变量。

　　　　　3.本脚本只创建c++语言的cocos2dx工程，创建成功后仍需手动配置c++ build目录。

个人写的脚本文下载地址：http://files.cnblogs.com/kuaixiaoqian/Create_Project.rar

2. 脚本内容

::------- ------------------创建cocos2dx工程脚本 ---------------------------------------
::---功能: 创建cocos2dx工程，基于cocos2dx 2.2.3 版本
::--------------------------------------------------------------------------------------
::---注意：此脚本运行前需设置COCOS2DX_DIR、NDK_DIR 变量值，设置为cocos2dx与ndk的目录
::------- 还需正确设置安装python2.7.6 以及将python路径加入到PATH环境变量中
::------- 此脚本可以放置在任何目录下
::--------------------------------------------------------------------------------------
::---使用：按照提示分别输入项目名称与包名称即可，
::--------脚本执行完成后，会在桌面创建到工程目录的快捷方式
::--------------------------------------------------------------------------------------
::---创建时间：2014.5.18------最后修改时间：2014.5.18 ---作者：酷爱小铅 ----------------
::--------------------------------------------------------------------------------------



@echo off
:: ------设置“必备”常数变量 (注意反斜杠方向)-----
set COCOS2DX_DIR=D:/cocos2d-x-2.2.3
set NDK_DIR=D:/Tools/android-ndk-r9d


:: -----提示输入项目名称与包名称
set /p projectName=请输入项目名称：  
if "%projectName%"=="" goto inputError  
set /p packageName=请输入包标示名(xxx.xxx.xxx 格式)：  
if "%packageName%"=="" goto inputError  


::-------创建工程，默认在cocos2dx/projects文件夹下
cd /d %COCOS2DX_DIR%/tools/project-creator
create_project.py -project %projectName% -package %packageName% -language cpp   

::------修改默认的项目设置----
echo 正在修改项目相关设置..... 

set NDK_MODULE_PATH= %COCOS2DX_DIR%;%COCOS2DX_DIR%/cocos2dx/platform/third_party/android/prebuilt
echo NDK_MODULE_PATH:=%NDK_MODULE_PATH%>>%COCOS2DX_DIR%/projects/%projectName%/proj.android/jni/Application.mk

::----创建桌面快捷方式 ----
echo [InternetShortcut] >"%USERPROFILE%\Desktop\%projectName%.url"
echo URL="%COCOS2DX_DIR%\projects\%projectName%" >>"%USERPROFILE%\Desktop\%projectName%.url"
echo IconIndex=0 >>"%USERPROFILE%\Desktop\%projectName%.url"
echo IconFile="%COCOS2DX_DIR%\template\multi-platform-js\proj.win32\res\game.ico" >>"%USERPROFILE%\Desktop\%projectName%.url"


echo 成功................
::-------退出与出错处理-------
pause  
exit  

:inputError  
@echo 项目名称或者包标示名不能为空！  
pause