2个8位移位寄存器驱动4位数码管

#include <TimerOne.h>

#define NUM_0   B11111100
#define NUM_1   B01100000
#define NUM_2   B11011010
#define NUM_3   B11110010
#define NUM_4   B01100110
#define NUM_5   B10110110
#define NUM_6   B10111110
#define NUM_7   B11100000
#define NUM_8   B11111110
#define NUM_9   B11100110

#define NUM_NULL   B0

int nLatchPin = 8;
int nClockPin = 12;
int nDataPin = 13;

int nCurInt = 9999;
void setup()
{
  pinMode(nLatchPin, OUTPUT);
  pinMode(nClockPin, OUTPUT);
  pinMode(nDataPin, OUTPUT);

  Timer1.initialize(10000);
  Timer1.attachInterrupt( Update ); // attach the service routine here
}

void Update()
{
  LightUpInt(nCurInt, 10);
}

void loop()
{
  delay(100);
  
  if (nCurInt > 0)
    nCurInt--;
}

byte GetNumberDefine(byte nNumber0_9)
{
  switch(nNumber0_9)
  {
    case 0: return NUM_0;
    case 1: return NUM_1;
    case 2: return NUM_2;
    case 3: return NUM_3;
    case 4: return NUM_4;
    case 5: return NUM_5;
    case 6: return NUM_6;
    case 7: return NUM_7;
    case 8: return NUM_8;
    case 9: return NUM_9;
  }  
  return 0;
}

// Light Up an integer, It can be more than 9, such as 123, but must less than 999
void LightUpInt(int nNumbers, int nMicrosecond)
{
  int nLow = 0;
  int nCount = 1;
  do{
    nLow = nNumbers % 10;
    nNumbers = nNumbers / 10;
    LightUpNumberOffset(GetNumberDefine(nLow), nCount);
    if (nMicrosecond > 0)
      delayMicroseconds(nMicrosecond);
    nCount++;
  }while(nNumbers > 0 && nCount < 5);
  
  if (nMicrosecond > 0)
    LightUpNumberOffset(NUM_NULL, 0);
}

void LightUpNumberOffset(byte dataOut, byte offset/*0 if light off, 1 - 4 if light up*/)
{
  digitalWrite(nLatchPin, LOW);  
  if (offset == 0)
  {
    LightUpOneDigital(0);
    LightUpOneDigital(dataOut);
  }
  else
  {
    LightUpOneDigital(~(1 << (3 + offset)));
    LightUpOneDigital(dataOut);
  }
  digitalWrite(nLatchPin, HIGH);
}

void LightUpOneDigital(byte dataOut)
{
  digitalWrite(nDataPin, LOW);
  digitalWrite(nClockPin, LOW);
  
  boolean bStatePin;
  
  for (int i=0; i<=7; i++)
  {        
    if (dataOut & (1 << i))
      bStatePin = HIGH;
    else
      bStatePin = LOW;
    
    digitalWrite(nClockPin, LOW);
    digitalWrite(nDataPin, bStatePin);
    digitalWrite(nClockPin, HIGH);
    
    //digitalWrite(nDataPin, LOW);
  }
  
  digitalWrite(nClockPin, LOW);
}